ADS1115 Guide: Wiring, Gain & Accuracy, and How to Spot a Fake Module

Is this your problem?

• “ADS1115 not found” on the I²C bus
• Readings stuck at 32767 (or 32752)
• Raw values only ever change in steps of 16
• Readings are wrong above about 3.3 V
• Values jump although the input is steady
• It seems faster or slower than the data rate you set

What the ADS1115 does, in one picture

The ADS1115 is a 16-bit ADC with four inputs, a programmable gain amplifier (PGA) and its own voltage reference, so its readings don’t depend on your board’s noisy 3.3 V or 5 V like the built-in ADC does. It talks I²C, so you only need four wires.

Pick the right gain for your signal

The gain range sets both the largest voltage you can read and the size of one step. Choose your supply and your signal’s highest voltage; the calculator picks the best range, warns about inputs above VDD, and gives you the code. Drag the slider to see where any input lands.

The 2-minute test: is my ADS1115 genuine?

Cheap ADS1115 modules sometimes carry a 12-bit chip. Makers have reported modules labelled ADS1115 that only deliver 12-bit data, and chips that behave like the cheaper ADS1015. The chip marking alone isn’t proof: TI marks the ADS1115 BOGI and the ADS1015 BRPI, but relabelled chips with the right marking have been reported. Two behaviours give a fake away:

1. It converts too fastThe same data-rate setting runs an ADS1015 about 16 times faster: 128 instead of 8 samples per second, 1600 instead of 128. Time the conversions and you can tell them apart.
2. The lowest 4 bits never changeA 12-bit result is stored in the 16-bit register shifted left by 4, so the raw value always steps by 16. On a genuine ADS1115 those bits change with the input.
3. Enter your results belowRun the sketch with about 1 V on A0 (for example a divider from 3.3 V), then type what the Serial Monitor prints.

#include <Wire.h>
#include <Adafruit_ADS1X15.h>
Adafruit_ADS1115 ads;

float measureRate(uint16_t rate) {
  ads.setDataRate(rate);
  const int N = 20;
  unsigned long t0 = micros();
  for (int i = 0; i < N; i++) {
    ads.startADCReading(ADS1X15_REG_CONFIG_MUX_SINGLE_0, false);
    while (!ads.conversionComplete()) {}
    ads.getLastConversionResults();
  }
  return N * 1e6 / (micros() - t0);
}

void setup() {
  Serial.begin(115200);
  if (!ads.begin(0x48)) { Serial.println("ADS1115 not found"); while (1); }
  Wire.setClock(400000);
  ads.setGain(GAIN_TWO);
  Serial.print("Rate at 8 SPS setting:   "); Serial.println(measureRate(RATE_ADS1115_8SPS), 1);
  Serial.print("Rate at 128 SPS setting: "); Serial.println(measureRate(RATE_ADS1115_128SPS), 1);
  ads.setDataRate(RATE_ADS1115_128SPS);
  uint16_t lowBits = 0;
  for (int i = 0; i < 64; i++) lowBits |= (ads.readADC_SingleEnded(0) & 0x000F);
  Serial.println(lowBits ? "Lowest 4 bits change: 16-bit data" : "Lowest 4 bits always 0: 12-bit data");
}

void loop() {}

Expect the measured rate to be a little below the setting on a genuine chip, because each single-shot reading adds I²C time. A clearly faster result at the 8 SPS setting is the giveaway.

Wire it right in 3 steps

1. Match the supply to your boardVDD to 3.3 V on an ESP32, Raspberry Pi or Pico; 5 V or 3.3 V on an Arduino Uno. Most modules have I²C pull-up resistors to their own VDD, so a 5 V module pulls the ESP32's SDA and SCL to 5 V.
2. Set the address and connect I²CADDR to GND gives 0x48. SDA and SCL to the board's I²C pins (ESP32: GPIO21 and GPIO22; Uno: A4 and A5; Pi: GPIO2 and GPIO3). Keep the wires short. Run an I²C scanner if the library says "not found".
3. Keep inputs inside 0 to VDDConnect the sensor output to A0 and its ground to the module's GND. Signals above VDD need a divider or a front-end. Add 1 kΩ in series and 100 nF to GND at the input for protection and filtering.

Which board are you using?

Still wrong? Other common causes

Frequently asked questions

© Ramanu Systems · Precision electronics modules, Made in India · ADS1115 specifications, input impedance, noise and the FSR-versus-VDD rule from the Texas Instruments ADS1115 datasheet. Fake-chip reports from the Arduino forum ("Achtung Fälschungen! ADS1115") and Cognitive Technophysicist ("Fake TI ADS1115 ADC sold as ADS1015"). ESP32 ADC figures from the Espressif ESP32 datasheet. Found an error? Tell us and we will fix it and credit you.